* * * * * * * * *
* Philips_EE.txt
* * * * * * * * *
* Models for Philips-EE components (and some non-Philips-EE ones -> some JFETS, MOSFETS) that are generally 
*    not present anymore in recent LT-Spice standard libraries. 
* Compiled by: Jurjen Kranenborg (not the originator of the data itself!): https://www.kranenborg.org
* --> for this reason this file is just a one-time compilation of publicly available data, not a proper reference for any other usage 
*     than for the Philips EE kits!
* Sources for this data: 
*    1) https://ltwiki.org/index.php?title=Standard.bjt
*    2) https://ltwiki.org/index.php?title=Standard.dio
*    3) https://ltwiki.org/index.php?title=Standard.jft
*    4) Anything else on the public net ...
* Versions of this file:
*    V1.0: first release (12-07-2025), did not pass the newest LT-SPICE checker when trying to run a model ... o:-(
*    V1.1: Update (15-07-2025) successfully used for new installation of LT-Spice x64, 24.1.19 (2025):
*       - BC548C incorrectly specced removed from V1.0 of this list (use BC547C instead)
*       - BC547B and BC547C are in the standard library, so removed from V1.0 of this list,
*       - BC549C and BC550C (identical) added as useful low-noise models and modern replacements for NPN's,
*       - BC559C and BC560C (identical) added as useful low-noise models and modern replacements for PNP's,
*    V1.2: Varicaps added
*       - AM Varactors (non-Philips_EE) BB112 and BB212 since they are useful in Philips EE projects as well, 
*         e.g. https://www.kranenborg.org/electronics-philips-ee
*    V1.3: Varicaps added:
*       - BB110 (EE2001 series) Varicap: Model construction from datasheet and added to list
*       - BB109 (non-Philips_EE) Varicap: idem. This is an interesting variant with a larger capacitance range and lower limit than the BB110
*    V1.4: Developed and published an Excel-model for converting datasheet data of a varicap directly to the corresponding LT-Spice model formulation
*       - Link to the MS-Excel file (which is self-explanatory): 
*         https://www.kranenborg.org/ee/projects/LTSpice/Varicap%20Spice%20model%20-%20nonlinear-equations-using-Solver.xlsx 
*    V1.5: Varicap added:
*       - BB209 (non-Philips_EE) Varicap: similar to BB109, but slightly larger C range and lower starting C value, so very interesting.


* .dio models:
* ------------
.model OA91 D(Is=19.43u N=2.986 Rs=65.98 Ikf=0 Xti=3 Eg=1.11 Cjo=1.326p M=.3333 Vj=.75 Fc=.5 Isr=2.787u Nr=1.954 Bv=100 Ibv=100u Tt=5n type=germanium)
.model OA95 D(is=68.06u N=4.056 Rs=45.41 Ikf=78.67 Xti=3 Cjo=1.326p M=.3333 Vj=.75 Fc=.5 Isr=10.42E-21 Nr=4.612 Bv=100 Ibv=100u Tt=5n type=germanium)
.MODEL BA318 D(IS=25.1N RS=1.08 N=2 BV=66.6 IBV=20N CJO=1.8P VJ=.75 M=.333 TT=3.76N)
* Varicaps/varactors - - - -:
.MODEL BB109 D(RS=0.5 CJ0=125.928e-12 VJ=0.75 M=0.9123773)
.MODEL BB209 D(RS=0.85 CJ0=1.1303E-10 VJ=0.75 M=1.0458E+00)
.MODEL BB110 D(RS=0.4 CJ0=68.4762e-12 VJ=0.75 M=0.4924077)
.MODEL BB112 D(IS=1e-14 RS=0.0011 CJO=2.324n VJ=0.75 TT=5n M=0.9 BV=100 XTI=3 FC=0.5 IBV=0.0001)
.MODEL BB212 D(IS=1e-14 RS=0.0011 CJO=7.202e-10 VJ=10 TT=5n M=0.9 BV=100 XTI=3 FC=0.5 IBV=0.0001)

* .jft models:
* ------------
.MODEL BF244A NJF(Beta=1.754m Betatce=-500m Rd=1 Rs=1 Lambda=2.667m Vto=-1.409 Vtotc=-2.5m Is=33.57f Isr=322.4f N=1 Nr=2 Xti=3 Alpha=311.7 Vk=243.6 Cgd=3.35p M=362.2m Pb=1 Fc=500m Cgs=3.736p Kf=1.356e-002f Af=1)
.model BF245A NJF(VTO=-1.7372 BETA=1.16621E-003 LAMBDA=1.77211E-002 RD=9.01678 RS=9.01678 IS=2.91797E-016 CGS=2.20000E-012 CGD=2.20000E-012 PB=0.780988 FC=0.5 mfg=NXP)
.model BF245B NJF(VTO=-2.3085 BETA=1.09045E-003 LAMBDA=2.31754E-002 RD=7.77648 RS=7.77648 IS=2.59121E-016 CGS=2.00000E-012 CGD=2.20000E-012 PB=0.991494 FC=0.5 mfg=NXP)
.model BF245C NJF(VTO=-5.0014 BETA=5.43157E-004 LAMBDA=2.71505E-002 RD=12.0869 RS=12.0869 IS=3.64346E-016 CGS=2.00000E-012 CGD=2.00000E-012 PB=1.24659 FC=0.5 mfg=NXP)
.MODEL J201 NJF(Beta=1.621m Betatce=-500m Rd=1 Rs=1 Lambda=2.236m Vto=-600m Vtotc=-2.5m Is=114.5f Isr=1.091p N=1 Nr=2 Xti=3 Alpha=506.8u Vk=251.7 Cgd=4.667p M=227.1m Pb=500m Fc=500m Cgs=2.992p Kf=0.6042f Af=1)

* .bjt models:
* ------------
* NPN - - - -: 
.MODEL BF494 npn(IS=3.0731e-10 BF=140 BR=1 CJE=2p CJC=2p VJE=0.75 VJC=0.75 TF=5.174e-10 TR=1e-08 MJE=0.33 MJC=0.33 VA=100 IKF=0.01 VAR=100 IKR=0.01 XTF=10 VTF=10 ITF=1 PTF=0 XTB=0 EG=1.11 XTI=3 FC=0.5)
.model BF495 NPN(IS=3.0731e-10 BF=80 BR=1 CJE=2p CJC=2p VJE=0.75 VJC=0.75 TF=5.174e-10 TR=1e-08 MJE=0.33 MJC=0.33 VA=100 IKF=0.01 VAR=100 IKR=0.01 XTF=10 VTF=10 ITF=1 XTB=0 EG=1.11 XTI=3) 
.MODEL BC547A NPN(IS=1.533E-14 ISE=7.932E-16 ISC=8.305E-14 XTI=3 BF=178.7 BR=8.628 IKF=0.1216 IKR=0.1121 XTB=1.5 VAF=69.7 VAR=44.7 VJE=0.4209 VJC=0.2 RE=0.6395 RC=0.6508 RB=1 RBM=1 IRB=1E-06 CJE=1.61E-11 CJC=4.388p XCJC=0.6193 FC=0.7762 NF=1.002 NR=1.004 NE=1.436 NC=1.207 MJE=0.3071 MJC=0.2793 TF=4.995E-10 TR=1m2 ITF=0.7021 VTF=3.523 XTF=139 EG=1.11 VCEO=50 ICRATING=100m MFG=PHILIPS)
.model BC548A NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=127.9 Bf=253 Ise=96.26f Ne=1.556 Ikf=77.05m Nk=.5305 Xtb=1.5 Br=1 Isc=130.8f Nc=1.602 Ikr=3.321 Rc=.8766 Cjc=5.25p Mjc=.3147 Vjc=.5697 Fc=.5 Cje=11.5p Mje=.6715 Vje=.5 Tr=10n Tf=409.5p Itf=1.994 Xtf=40.12 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)
.model BC548B NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=62.79 Bf=374.6 Ise=68f Ne=1.576 Ikf=81.57m Nk=.4767 Xtb=1.5 Br=1 Isc=12.4f Nc=1.835 Ikr=3.924 Rc=.9747 Cjc=5.25p Mjc=.3147 Vjc=.5697 Fc=.5 Cje=11.5p Mje=.6715 Vje=.5 Tr=10n Tf=410.2p Itf=1.491 Xtf=40.06 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)
.MODEL BC549B NPN(IS=4.679E-14 ISE=2.642f ISC=2.337E-14 XTI=3 BF=458.7 BR=11.57 IKF=0.1371 IKR=0.1144 XTB=1.5 VAF=52.64 VAR=364.5 VJE=0.5591 VJC=0.1994 RE=0.2598 RC=1 RB=1 RBM=1 IRB=1E-06 CJE=1.229E-11 CJC=4.42p XCJC=0.6193 FC=0.7936 NF=1.01 NR=1.019 NE=1.581 NC=1.164 MJE=0.3385 MJC=0.2782 TF=4.689E-10 TR=1m2 ITF=0.8842 VTF=2.828 XTF=160 EG=1.11 VCEO=30 ICRATING=100m MFG=PHILIPS)
.model BC549C NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=23.89 Bf=493.2 Ise=99.2f Ne=1.829 Ikf=.1542 Nk=.6339 Xtb=1.5 Br=2.886 Isc=7.371p Nc=1.508 Ikr=5.426 Rc=1.175 Cjc=5.5p Mjc=.3132 Vjc=.4924 Fc=.5 Cje=11.5p Mje=.6558 Vje=.5 Tr=10n Tf=420.3p Itf=1.374 Xtf=39.42 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)
.model BC550C NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=23.89 Bf=493.2 Ise=99.2f Ne=1.829 Ikf=.1542 Nk=.6339 Xtb=1.5 Br=2.886 Isc=7.371p Nc=1.508 Ikr=5.426 Rc=1.175 Cjc=5.5p Mjc=.3132 Vjc=.4924 Fc=.5 Cje=11.5p Mje=.6558 Vje=.5 Tr=10n Tf=420.3p Itf=1.374 Xtf=39.42 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)
* PNP - - - -:
.model BC557C PNP(IS=5.83E-14 NF=1.009 ISE=3.88E-15 NE=1.408 BF=516.7 IKF=0.08039 VAF=26.03 NR=1.006 ISC=4.01E-14 NC=1.313 BR=12.45 IKR=0.07238 VAR=6.717 RB=1 IRB=1.00E-06 RBM=1 RE=0.5685 RC=0.6257 XTB=0 EG=1.11 XTI=3 CJE=1.26E-11 VJE=0.3809 MJE=0.3545 TF=5.23E-10 XTF=4.339 VTF=5.425 ITF=0.1896 PTF=0 CJC=7.80E-12 VJC=0.5897 MJC=0.4569 XCJC=0.6288 TR=1.00E-32 CJS=0 VJS=0.75 MJS=0.333 FC=0.5729 Vceo=45 Icrating=100m mfg=Philips)
.MODEL BC559B PNP(IS=5.826E-14 ISE=3.884f ISC=4.014E-14 XTI=3 BF=516.7 BR=12.45 IKF=0.08039 IKR=0.07238 XTB=1.5 VAF=26.03 VAR=6.717 VJE=0.3809 VJC=0.5897 RE=0.5685 RC=0.6257 RB=1 RBM=1 IRB=1E-06 CJE=1.26E-11 CJC=7.798p XCJC=0.6288 FC=0.5729 NF=1.009 NR=1.006 NE=1.408 NC=1.313 MJE=0.3545 MJC=0.4569 TF=5.233E-10 TR=1m2 ITF=0.1896 VTF=5.425 XTF=4.339 EG=1.11 VCEO=45 ICRATING=100M MFG=PHILIPS)
.model BC559C PNP(Is=1.02f Xti=3 Eg=1.11 Vaf=34.62 Bf=401.6 Ise=38.26p Ne=5.635 Ikf=74.73m Nk=.512 Xtb=1.5 Br=9.011 Isc=1.517f Nc=1.831 Ikr=.1469 Rc=1.151 Cjc=9.81p Mjc=.332 Vjc=.4865 Fc=.5 Cje=30p Mje=.3333 Vje=.5 Tr=10n Tf=524p Itf=.9847 Xtf=17.71 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)
.model BC560C PNP(Is=1.02f Xti=3 Eg=1.11 Vaf=34.62 Bf=401.6 Ise=38.26p Ne=5.635 Ikf=74.73m Nk=.512 Xtb=1.5 Br=9.011 Isc=1.517f Nc=1.831 Ikr=.1469 Rc=1.151 Cjc=9.81p Mjc=.332 Vjc=.4865 Fc=.5 Cje=30p Mje=.3333 Vje=.5 Tr=10n Tf=524p Itf=.9847 Xtf=17.71 Vtf=10 Vceo=30 Icrating=100m mfg=Philips)

* .fet models (Mosfet):
* ------------
*
.SUBCKT BSN254A   10 20 40
* 10=drain  20=gate  40=source
M1   1  2  3  3  DMOS L=1U W=1U
RD  10  1  2.85
RS  30  3  .151
RG  20  2  5
CGS  2  3  60P
EGD 12  0  2  1  1
VFB 14  0  0
FFB  2  1  VFB  1
CGD 13 14  64.2P
R1  13  0  1
D1  12 13  DLIM
DDG 15 14  DCGD
R2  12 15  1
D2  15  0  DLIM
DSD  3 10  DSUB
LS  30 40  3N
.MODEL DMOS NMOS (LEVEL=3 THETA=80M VMAX=521K ETA=2M VTO=1.4 KP=.52)
.MODEL DCGD D (CJO=64.2P VJ=.6 M=.68)
.MODEL DSUB D (IS=1.45N N=1.5 RS=1.35 BV=250 CJO=64.5P VJ=.8 M=.42 TT=102N)
.MODEL DLIM D (IS=100U)
.ENDS
* - - - - - - - - - - - - - -
.SUBCKT BS107A 1 2 3
* 1=drain  2=gate  3=source
Cgs  6 3 36.5e-12
Cgd1 6 4 123e-12
Cgd2 1 4 3.5e-12
M1 5 6 3 3 MOST1
M2 4 6 5 3 MOST2
D1 3 5 Dbody
Rd 5 1 Rtemp 4.1
Rg 2 6 10
.MODEL MOST1 NMOS(Level=3 Vto=1.8 Kp=1.63e-7 Eta=3e-6 W=0.1 L=0.1e-6
+                Rs=0 Rd=0 Ld=0 Wd=0 Uo=500 Vmax=4e7 
+                Xj=5e-7 Kappa=0.08 Nfs=3e12 Theta=5e-3 Tpg=1
+                Cgbo=0 Cgso=0 Cgdo=0 Delta=0.1 Is=0)
.MODEL MOST2 NMOS(Level=3 Vto=-3.3 Kp=1e-7 Eta=3e-6 W=5e-4 L=0.1e-6
+                Rs=0 Rd=0 Ld=0 Wd=0 Uo=500 Vmax=0 
+                Xj=0 Kappa=0.2 Nfs=0 Theta=0 Tpg=1
+                Cgbo=0 Cgso=0 Cgdo=0 Delta=0 Is=0)
.MODEL Dbody D(Is=1e-14 N=0.8 Rs=0 Ikf=1e3 Cjo=0 M=0.5 Vj=0.4
+                Bv=200 Ibv=10e-6 Tt=40e-9)
.MODEL Rtemp RES(TC1=9e-3 TC2=3.1e-5)
.ENDS
* - - - - - - - - - - - - - -